######################################################################
#
# EPrints::MetaField::License;
#
######################################################################
#
#  This file is part of GNU EPrints 2.
#  
#  Copyright (c) 2000-2004 University of Southampton, UK. SO17 1BJ.
#  
#  EPrints 2 is free software; you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation; either version 2 of the License, or
#  (at your option) any later version.
#  
#  EPrints 2 is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#  
#  You should have received a copy of the GNU General Public License
#  along with EPrints 2; if not, write to the Free Software
#  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
######################################################################

=pod

=head1 NAME

B<EPrints::MetaField::License> - A named URL

=head1 DESCRIPTION

A URL that also contains a multi-language label. It is rendered as a link on the label.

=head1 SEE ALSO

L<EPrints::DataObj::License>

=over 4

=cut

# datasetid

package EPrints::MetaField::License;

use strict;
use warnings;

BEGIN
{
	our( @ISA );

	@ISA = qw( EPrints::MetaField::Set );
}

use EPrints::MetaField::Set;

sub render_single_value
{
	my( $self, $session, $value ) = @_;
	
	my $ds = $session->get_repository->get_dataset(
			$self->get_property( "datasetid" ) );
	my $obj = $session->get_database->get_single( $ds, $value );

	my $text = $session->make_text( $obj->get_label() );

	return $text if( $self->{render_dont_link} );

	my $a = $session->render_link( $obj->get_url() );
	$a->appendChild( $text );

	return $a;
}

sub tags_and_labels
{
	my( $self, $session ) = @_;

	my $ds = $session->get_repository->get_dataset(
			$self->get_property( "datasetid" ) );

	return $ds->make_object( $session, {} )->tags_and_labels( $session, $ds );
}

sub get_values { get_unsorted_values( @_ ) }

sub get_unsorted_values
{
	my( $self, $session, $dataset, %opts ) = @_;

	my( $tags, undef ) = $self->tags_and_labels( $session );

	return $tags;
}

sub get_value_label
{
	my( $self, $session, $value ) = @_;

	my $ds = $session->get_repository->get_dataset( 
			$self->{datasetid} );	

	return $session->make_text(
		$ds->get_object( $session, $value )->get_label()
	);
}

sub get_property_defaults
{
	my( $self ) = @_;
	my %defaults = $self->SUPER::get_property_defaults;
	$defaults{datasetid} = $EPrints::MetaField::REQUIRED;
	delete $defaults{options}; # inherrited but unwanted
	return %defaults;
}

######################################################################
1;
